proe漸開線變位直齒圓柱齒輪實體模型(二)

2013-07-05 by:廣州CAD:proe設計培訓中心來源:仿真在線

proe漸開線齒輪:

5.2 b種情況的齒輪自動化設計Program原程序

VERSION
REVNUM 60662
LISTING FOR PART GEAR_B

INPUT
Z1 NUMBER    /*齒輪1齒數
"Enter Z1: "
Z2 NUMBER    /*齒輪2齒數
"Enter Z2: "
M NUMBER    /*模數
"Enter M: "
X1 NUMBER   /*齒輪1變位系數
"Enter x1:"
X2 NUMBER   /*齒輪2變位系數
"Enter x2:"
ALPHA NUMBER /*壓力角
"Enter the pressure angle: "
GEAR_WIDTH NUMBER /*齒輪寬度
"Enter the gear width: "
RAD_FILLET NUMBER   /*齒槽圓角半徑
"Enter rad_fillet:"
SHAFT_DIA NUMBER    /*軸孔直徑
"Enter shaft_dia:"
KEY_WIDTH NUMBER   /*鍵槽寬度
"Enter key_width:"
KEY_HEIGHT NUMBER /*鍵槽高度
"Enter key_height:"
END INPUT

RELATIONS
INVA=TAN(ALPHA)-ALPHA*PI/180
      /*標準壓力角時的漸開線函數值
INVAP=2*(X1+X2)*TAN(ALPHA)/(Z1+Z2)
+INVA
/*計算嚙合角時的漸開線函數值
AP=10
SOLVE         /*解方程程序
INVAP=TAN(AP)-AP*PI/180
FOR AP
HA=1           /*齒頂高系數
IF M<1          /*徑向間隙系數的確定
   C=0.35
ELSE
   C=0.25
ENDIF
R1 = 0.5*M*Z1   /*齒輪1分度圓半徑
R2 = 0.5*M*Z2   /*齒輪1分度圓半徑
D = R1+R2      /*標準中心距
RD = D*COS(ALPHA)/COS(AP)
               /*實際中心距
RB1 = R1*COS(ALPHA)   /*基圓半徑
RF1 = R1-M*(HA+C-X1)   /*齒根圓半徑
RA1 = RD-R2+M*(HA-X2) /*齒頂圓半徑
THICK1 = M*(0.5*PI+2*X1*TAN(ALPHA))
              /*分度圓上齒厚(弧長)
TOOTH_THICK1=THICK1*COS(ALPHA)
+2*RB1*INVA /*基圓上齒厚(弧長)
ANG_TOOTH_THICK1=TOOTH_THICK1/RB1*180/PI        /*基圓上齒厚角(度)
D0=RA1           /*內部參數賦值
D1=GEAR_WIDTH
D2=360/Z1
D3=ANG_TOOTH_THICK1
D4=180/Z1
D5=RB1
D13=RF1
D14=RAD_FILLET
D15=360/Z1
P16=Z1
D116=SHAFT_DIA
D117=KEY_HEIGHT
D118=KEY_WIDTH
END RELATIONS

5.3 結合a和b兩種情況后的齒輪自動化設計Program原程序
VERSION
REVNUM 145
LISTING FOR ASSEMBLY GEAR

INPUT
Z1 NUMBER    /*齒輪1齒數
"Enter Z1: "
Z2 NUMBER    /*齒輪2齒數
"Enter Z2: "
M NUMBER    /*模數
"Enter M: "
X1 NUMBER   /*齒輪1變位系數
"Enter x1:"
X2 NUMBER   /*齒輪2變位系數
"Enter x2:"
ALPHA NUMBER /*壓力角
"Enter the pressure angle: "
GEAR_WIDTH NUMBER /*齒輪寬度
"Enter the gear width: "
RAD_FILLET NUMBER   /*齒槽圓角半徑
"Enter rad_fillet:"
SHAFT_DIA NUMBER    /*軸孔直徑
"Enter shaft_dia:"
KEY_WIDTH NUMBER   /*鍵槽寬度
"Enter key_width:"
KEY_HEIGHT NUMBER /*鍵槽高度
"Enter key_height:"
END INPUT

RELATIONS
HA=1           /*齒頂高系數
IF M<1          /*徑向間隙系數的確定
   C=0.35
ELSE
   C=0.25
ENDIF
R1 = 0.5*M*Z1   /*齒輪1分度圓半徑
RB1 = R1*COS(ALPHA)   /*基圓半徑
RF1 = R1-M*(HA+C-X1)   /*齒根圓半徑
END RELATIONS
……………
IF RF1<RB1 /*齒根圓半徑<基圓半徑時,加入
/*a種情況齒輪,否則加入b種情況齒輪
     EXECUTE PART GEAR_A
                  /*執行a種情況齒輪
     Z1 = Z1      /*外部參數輸入
     Z2 = Z2
     M = M
     X1 = X1
     X2 = X2
     ALPHA = ALPHA
     GEAR_WIDTH = GEAR_WIDTH
     RAD_FILLET = RAD_FILLET
     SHAFT_DIA = SHAFT_DIA
     KEY_WIDTH = KEY_WIDTH
     KEY_HEIGHT = KEY_HEIGHT
     END EXECUTE

     ADD PART GEAR_A   /*加入a種齒輪
     INTERNAL COMPONENT ID 39
     END ADD

ELSE
     EXECUTE PART GEAR_B
                   /*執行b種情況齒輪
     Z1 = Z1       /*外部參數輸入
     Z2 = Z2
     M = M
     X1 = X1
     X2 = X2
     ALPHA = ALPHA
     GEAR_WIDTH = GEAR_WIDTH
     RAD_FILLET = RAD_FILLET
     SHAFT_DIA = SHAFT_DIA
     KEY_WIDTH = KEY_WIDTH
     KEY_HEIGHT = KEY_HEIGHT
     END EXECUTE

     ADD PART GEAR_B /*加入b 種齒輪
     INTERNAL COMPONENT ID 40
     END ADD
END IF
6 造型實例

圖5是本二次開發軟件在proeNGINEER軟件中自動生成的圓柱齒輪實體模型。

其設計參數是:
齒數z1=20                     齒數z2=30
模數m=3                       變位系數x1=0.1
變位系數x2=0.2            壓力角=200
齒槽圓角半徑=0.2       齒寬=15
軸孔直徑=20                鍵槽寬度=8
鍵槽高=3